Sollya User's Manual

Name:

rename rename the free variable.

Library name:

void sollya_lib_name_free_variable(const char *)

Usage:

rename(ident1,ident2) : void

Parameters:

ident1 is the current name of the free variable.
ident2 is a fresh name.

Description:

rename permits a change of the name of the free variable. Sollya can handle only one free variable at a time. The first time in a session that an unbound name is used in a context where it can be interpreted as a free variable, the name is used to represent the free variable of Sollya. In the following, this name can be changed using rename.
Be careful: if ident2 has been set before, its value will be lost. Use the command isbound to know if ident2 is already used or not.
If ident1 is not the current name of the free variable, an error occurs.
If rename is used at a time when the name of the free variable has not been defined, ident1 is just ignored and the name of the free variable is set to ident2.
It is always possible to use the special keyword _x_ to denote the free variable. Hence ident1 can be _x_.
Notice that ident2 is an identifier, not a string. In particular, it is not directly possible to use the content of a variable to provide the new name of the free variable. This can however be obtained using a level of indirection: first create a string that contains the call to rename, and then evaluate it thanks to parse (see example below).

Example 1:

   > f=sin(x);
   > f;
   sin(x)
   > rename(x,y);
   > f;
   sin(y)

Example 2:

   > a=1;
   > f=sin(x);
   > rename(x,a);
   > a;
   a
   > f;
   sin(a)

Example 3:

   > verbosity=1!;
   > f=sin(x);
   > rename(y, z);
   Warning: the current free variable is named "x" and not "y". Can only rename the free variable.
   The last command will have no effect.
   > rename(_x_, z);
   Information: the free variable has been renamed from "x" to "z".

Example 4:

   > verbosity=1!;
   > rename(x,y);
   Information: the free variable has been named "y".
   > isbound(x);
   false
   > isbound(y);
   true

Example 5:

   > verbosity=1!;
   > f = sin(x);
   > new_varname = "foo";
   > rename(_x_, new_varname);
   Information: the free variable has been renamed from "x" to "new_varname".
   > f;
   sin(new_varname)
   > rename(_x_, x);
   Information: the free variable has been renamed from "new_varname" to "x".
   > new_varname = "foo";
   > str = "rename(_x_, " @ new_varname @ ");";
   > (parse("proc () { " @ str @ "}"))();
   Information: the free variable has been renamed from "x" to "foo".
   > f;
   sin(foo)

Example 6:

   > verbosity=1!;
   > f = sin(x);
   > f;
   sin(x)
   > rename(x, _x_);
   Information: the free variable has been renamed from "x" to "_x_".
   > f;
   sin(_x_)
   > g = cos(y);
   > f;
   sin(y)
   > g;
   cos(y)
   > rename(_x_, _x_);
   Information: the free variable has been renamed from "y" to "_x_".
   > f;
   sin(_x_)
   > g;
   cos(_x_)