Sollya User's Manual

Name:

@ concatenates two lists or strings or applies a list as arguments to a procedure

Library name:

sollya_obj_t sollya_lib_concat(sollya_obj_t, sollya_obj_t)

Usage:

L1@L2 : (list, list) -> list string1@string2 : (string, string) -> string proc@L1 : (procedure, list) -> any type

Parameters:

L1 and L2 are two lists.
string1 and string2 are two strings.
proc is a procedure or an external procedure.

Description:

In its first usage form, @ concatenates two lists or strings.
In its second usage form, @ applies the elements of a list as arguments to a procedure or an external procedure. In the case when proc is a procedure or external procedure with a fixed number of arguments, a check is done if the number of elements in the list corresponds to the number of formal parameters of proc. An empty list can therefore be applied only to a procedure that does not take any argument. In the case when proc accepts an arbitrary number of arguments, no such check is performed.

Example 1:

> [|1,...,3|]@[|7,8,9|];
[|1, 2, 3, 7, 8, 9|]

Example 2:

> "Hello "@"World!";
Hello World!

Example 3:

   > procedure cool(a,b,c) {
     write(a,", ", b," and ",c," are cool guys.\n");
     };
   > cool @ [| "Christoph", "Mioara", "Sylvain" |];
   Christoph, Mioara and Sylvain are cool guys.

Example 4:

   > procedure sayhello() {
     "Hello! how are you?";
     };
   > sayhello();
   Hello! how are you?
   > sayhello @ [||];
   Hello! how are you?

Example 5:

   > bashexecute("gcc -fPIC -Wall -c externalprocexample.c");
   > bashexecute("gcc -fPIC -shared -o externalprocexample externalprocexample.o");
   > externalproc(foo, "./externalprocexample", (integer, integer) -> integer);
   > foo;
   foo
   > foo @ [|5, 6|];
   11

Example 6:

   > procedure add(L = ...) {
     var acc, i;
     acc = 0;
     for i in L do acc = i + acc;
     return acc;
     };
   > add(1,2);
   3
   > add(1,2,3);
   6
   > add @ [|1, 2|];
   3
   > add @ [|1, 2, 3|];
   6
   > add @ [||];
   0

See also: .:, :., procedure, externalproc, proc, bind, getbacktrace

Go back to the list of commands